REM ************************************************************************
REM *                                                                      *
REM *                  SEFT pulse program - 000405, GMB                    *
REM *                                                                      *
REM * Spin-Echo Fourier Transform experiment for determination of 13C      *
REM * multiplicity. This ppg is for demonstration purposes - USE DEPT,     *
REM * REINEPT, or PENDANT for routine determination of 13C multiplicity    *
REM *                                                                      *
REM *       13C: -- d1 -- 90(x) -- d2 -- 180(x) -- d2 -- Acqu(x)           *
REM *                                                                      *
REM *       1H:  -- BBDEC --- | -- d2 -- | ------- BBDEC -------           *
REM *                                                                      *
REM * Were d2 is set to 1/JCH. The value of JCH has to match the type of   *
REM * carbon in order for the spin-echo to work properly...                *
REM *                                                                      *
REM * Do not read in conditions. Current conditions (NS, SW, DS, etc.)     *
REM * should be used.                                                      *
REM *                                                                      *
REM ************************************************************************
showwin
cls
print "SEFT Program for 13C Multiplicity Determination"
print
print "The relaxation delay needs to be set in the range 1 to 5"
print "times the expected T1 for the sample. 2.0 sec is a good"
print "general purpose value."
print
input "Enter a relaxation delay: ",d0
if d0=0 then d0=2
cls
define p0 x90 pulses.txt
print "SEFT Program for 13C Multiplicity Determination"
print
print "Setup the 13C pulsewidths."
print
if p0>0 then print "The observe 90 degree pulse chosen is ",p0,"us"
if p0=0 then input "Enter the observe 90 degree pulse: ",p0
p1=2*p0
SLEEP 1
cls
print "SEFT Program for 13C Multiplicity Determination"
print 
print "In order to get maximum 1H to 13C polarization"
print "transfer, the proper JCH coupling constant has"
print "to be known. An average can also be used."
input "Enter the JCH coupling constant (Hz): ",j
REM Calculate d2 as a function of JCH...
d2=1e6/j
cls
print "SEFT Program for 13C Multiplicity Determination"
print
print "Enter the number of blocks of data to acquire (default 1)."
print "Entering more than 1 block will automatically set the"
print "spectrometer to run in block averaging mode."
input "Number of blocks of data to acquire: ",b
if b<1 then b=1
if b=1 then goto 100
cls
print "SEFT Program for 13C Multiplicity Determination"
print
print "Enter a file name for the data. The default file"
print "my_seft can be used by pressing <Enter>. Any file"
print "with the same name will be overwritten without warning."
print
input "Enter output file name (data\my_seft): ",f$
if f$="" then f$="data\my_seft"
100 cls
print "Running SEFT..."
REM write 2D file header if running more than 1 block...
if b>1 then WH2D f$ b 0 0
REM Phase cycle is EXORCYCLE
a$ = "0000111122223333"
b$ = "0213132013202013"
c$ = "0022113300221133"
PROGRAM "clear"
PROGRAM 0 d0 S DEC BB FX PX
PROGRAM + 2.0 uS DEC BB FX PX 
PROGRAM + p0 uS TX FX PX a$
PROGRAM + d2 uS FX PX 
PROGRAM + p1 uS TX DEC BB FX PX b$ 
PROGRAM + d2 uS DEC BB FX PX
PROGRAM + 1.0 uS ADC RX DEC BB FX PX
PROGRAM + a S RX DEC BB FX PX
PROGRAM + 0.02 S RX DEC BB FX PX 
PROGRAM "coadd" c$
PROGRAM + 1.0 uS DEC BB FX PX
for i=1 to b
ZERO
START
if i=1 then wr "c:\eft\pnmr.fid"
if b=1 then goto 200
w=d0*i
WF f$ i w
cls
print "Running SEFT..."
print
print "Block",i,"of",b,"completed."
NEXT
200 cls
print "SEFT Experiment completed."
if b=1 then goto 300
print
print "Block averaging experiment completed. Total scans",n*(i-1),"."
input "<Enter> to continue...",g$
cls
print "Use <Alt+Tab> to transfer to NUTS for data processing."
print "First import and process the first block <a1>, select an"
print "isolated peak for registration, create zoom region 0 about it."
print "Then run aii_Cbapr.mac, which will align and add all blocks."
input "<Enter> to continue...",g$
cls
print "The raw data is saved as file",f$,"which will be"
print "overwritten without warning if the same name is used"
print "again. To save the data move it to another directory."
300 input "<Enter> to exit the pulse program...",g$
END