REM ***********************************************************************
REM *                                                                     *
REM *                            JAR - GMB 2000                           *
REM *                                                                     *
REM * Jump-and-return H1 program for solvent supression. The sequence is: *
REM *                                                                     *
REM *                   rd - (binomial pulse) - acquire                   *
REM *                                                                     *
REM *                               _    _         _   _                  *
REM * The binomial pulses can be: 1 1, 1 2 1, or 1 3 3 1. The tau delay   *
REM * needs to be supplied by the user as a SW. tau is choosen so that    *
REM * 1 / ( 2 * tau ) = SW. The carrier has to be on resonance with the   *
REM * line that needs to be supressed.                                    *
REM *                                                                     *
REM ***********************************************************************
showwin
cls
print "Jump-and-return program for H2O supression"
print
print "Enter the type of binomial pulse that will be used"
print "for excitation. The allowed pulses are 1: 1(-1),"
print "2: 1(-2)1, or 3: 1(-3)3(-1)."
input "Enter binomial pulse type (1, 2, or 3): ",l
cls
print "Jump-and-return program for H2O supression"
print
print "Enter the spectral window in which you have signals"
print "of interest. Lines on the edges of this spectral"
print "window will be supressed just as if they were the"
print "solvent, so think before going any further."
input "Enter the spectral window (Hz): ",v
if v=0 then v=1500
d1=1e6/(2*v)
cls
print "Jump-and-return program for H2O supression"
print 
print "The delay between experiments called the relaxation"
print "delay should be set to about four times the T1 of the"
print "lines in the sample."
input "Enter the relaxation delay: ",d0
cls
print "Jump-and-return program for H2O supression"
print
define p0 h90 pulses.txt
if p0=0 then input "Enter 90 degree pulsewidth: ",p0
if p0>0 then print "The 90 degree pulsewidth chosen is: ",p0
REM define the pulse lenghts of all possible pulses used for
REM the binomial pulse excitation...
p1=p0/4
p2=p0/2
p3=p0*3/4
print
print "Ready to run Jump-and-return H20 supression"
input "<Enter> to continue... ",g$
rem a$-c$ are transmitter/receiver phase cycles
a$ = "0123"
b$ = "2301"
c$ = "0123"
rem will use 3*dw/16 delay before turning receiver on
e=3*d/16
rem will use dw/16 delay before turning digitizer on
f=d/16
cls
print "Running Jump-and-return H20 supression..."
PROGRAM "clear"
PROGRAM 0 d0 S 
PROGRAM + 2.0 uS
if l = 1 then goto 200
if l = 2 then goto 300
if l = 3 then goto 400
100 PROGRAM + e uS 
PROGRAM + f uS RX 
PROGRAM + 1.0 uS ADC RX 
PROGRAM + a S RX 
PROGRAM "coadd" c$
PROGRAM + 1.0 uS
ZERO
START
WR "c:\eft\data\pnmr.fid"
cls
print "Jump-and-return program for H2O supression"
print
print n," scans completed" 
print
print "Transfer to Nuts with <Alt+Tab>. Run NutsLink <a1>"
print "to import and process the file. Correct the phase"
print "using PE. The spectrum will be negative for peaks"
print "with frequencies lower than 0, and positive for"
print "peaks with frequencies higher than 0. You can solve"
print "this problem by further processing with the NUTS"
print "macro usp_flipjar.mac."
print 
input "<Enter> to exit Jump-and-return... ",f$
goto 1000
rem This is the 1(x)-1-(-x) binomial...
200 PROGRAM + p0 uS TX a$
    PROGRAM + d1 uS
    PROGRAM + p0 uS TX b$
    goto 100
rem This is the 1(x)-2-(-x)-1-(x) binomial...
300 PROGRAM + p2 uS TX a$
    PROGRAM + d1 uS
    PROGRAM + p0 uS TX b$
    PROGRAM + d1 uS
    PROGRAM + p2 uS TX a$
    goto 100
rem This is the 1(x)-3-(-x)-3-(x)-1-(-x) binomial...
400 PROGRAM + p1 uS TX a$
    PROGRAM + d1 uS
    PROGRAM + p3 uS TX b$
    PROGRAM + d1 uS
    PROGRAM + p3 uS TX a$
    PROGRAM + d1 uS
    PROGRAM + p1 uS TX b$
    goto 100
1000 END