REM ***********************************************************************
REM *                                                                     *
REM *                          INVREC - GMB 2000                          *
REM *                                                                     *
REM * Inversion-recovery H1 program for solvent suppression. Uses pulse   *
REM * sequence:                                                           *
REM *                                                                     *
REM *                   rd - 180 - delay - 90 - acquire                   *
REM *                                                                     *
REM * The 180 pulse is done with a 90x - 180y - 90x composite pulse to    *
REM * correct for imperfections in the pulse lenght. The delay is entered *
REM * by the user and modified until a null is seen for the solvent.      *
REM *                                                                     *
REM ***********************************************************************
showwin
cls
print "Inversion-recovery program for H2O suppression"
print 
print "The delay between experiments called the relaxation"
print "delay should be set to about four times the T1 of the"
print "line you wish to cancel out."
input "Enter the relaxation delay: ",d0
cls
print "Inversion-recovery program for H2O suppression"
print
print "Enter the delay between the inversion (180) and the"
print "read (90) pulses. It should match the relaxation of"
print "the solvent peak, and should be modified until a null"
print "is obtained."
input "Enter the delay beween the 180 and 90 degree pulses: " ,d1
if d1=0 then d1=4
cls
print "Inversion-recovery program for H2O suppression"
print
define p0 h90 pulses.txt
if p0>0 then print "The 90 degree pulsewidth chosen is: ",p0
if p0=0 then input "Enter 90 degree pulsewidth: ",p0
p1=2*p0
print "The 180 degree pulsewidth chosen is: ",p1
print
print "Ready to run Inversion-recovery"
input "<Enter> to continue... ",g$
cls
print "Running Inversion-recovery"
rem a$-c$ are transmitter phase cycles
a$ = "0213"
b$ = "13"
c$ = "02"
rem will use 3*dw/16 delay before turning receiver on
e=3*d/16
rem will use dw/16 delay before turning digitizer on
f=d/16
PROGRAM "clear"
PROGRAM 0 d0 S 
PROGRAM + 2 uS c$
PROGRAM + p0 uS TX c$
PROGRAM + p1 uS TX b$
PROGRAM + p0 uS TX c$
PROGRAM + d1 S  
PROGRAM + p0 uS TX a$
PROGRAM + e uS 
PROGRAM + f uS RX 
PROGRAM + 1.0 uS ADC RX 
PROGRAM + a S RX 
PROGRAM "coadd" a$
PROGRAM + 1 uS
ZERO
START
wr "c:\eft\data\pnmr.fid"
cls
print "Inversion-recovery program for H2O suppression"
print
print n," scans completed" 
print
print "Transfer to Nuts with <Alt+Tab>. Run NutsLink <a1>"
print "to import and process the last file. Correct the"
print "phase using PE. Modify your d1 according to the"
print "residual solvent peak in the spectrum."
print 
input "<Enter> to exit Inversion-recovery program... ",f$
END