REM ************************************************************************
REM *                                                                      *
REM *                  INEPT+ pulse program - 000405, GMB                  *
REM *                                                                      *
REM * Insensitive Nuclei Enhanced by Polarization Transfer for 13C         *
REM * enhancement. This version has an additional purging pulse to correct *
REM * the intensities within multiplets. The pulse sequence is:            *
REM *                                                                      *
REM * 13C: ----|--- d2 -- 180 -- d2 -- 90 -- d3 -- 180 -- d3 -- 90 -- Acq  *
REM *                                                                      *
REM * 1H:  -- 90 -- d2 -- 180 -- d2 -- 90 -- d3 -- 180 -- d3 -- 90 -- CPD  *
REM *                                                                      *
REM * Were d2 is set to 1/4JCH and d3 to 1.5/4JCH. The value of JCH has to *
REM * match the type of carbon we are trying to enhance...                 *
REM *                                                                      *
REM * Do not read in conditions. Current conditions (NS, SW, DS, etc.)     *
REM * should be used.                                                      *
REM *                                                                      *
REM ************************************************************************
showwin
cls
print "INEPT+ Program for X Nuclei Enhancement"
print
print "The relaxation delay needs to be set in the range 1 to 5"
print "times the expected T1 for the sample. 2.0 sec is a good"
print "general purpose value."
print
input "Enter a relaxation delay: ",d0
if d0=0 then d0=2
cls
define p5 h90 pulses.txt
define p0 x90 pulses.txt
print "INEPT+ Program for X Nuclei Enhancement"
print
print "Setup the 13C and 1H pulsewidths."
print
if p5>0 then print "The decoupler 90 degree pulse chosen is ",p5,"us"
if p5=0 then input "Enter the decoupler 90 degree pulse: ",p5
p6=2*p5
if p0>0 then print "The observe 90 degree pulse chosen is ",p0,"us"
if p0=0 then input "Enter the observe 90 degree pulse: ",p0
p1=2*p0
SLEEP 1
cls
print "INEPT+ Program for X Nuclei Enhancement"
print 
print "In order to get maximum 1H to 13C polarization"
print "transfer, the proper JCH coupling constant has"
print "to be known. An average can also be used."
input "Enter the JCH coupling constant (Hz): ",j
REM Calculate d2 as a function of JCH...
d2=1e6/(4*j)
d3=1.5*d2
cls
print "INEPT+ Program for X Nuclei Enhancement"
print
print "Enter the number of blocks of data to acquire (default 1)."
print "Entering more than 1 block will automatically set the"
print "spectrometer to run in block averaging mode."
input "Number of blocks of data to acquire: ",b
if b<1 then b=1
if b=1 then goto 100
cls
print "INEPT+ Program for X Nuclei Enhancement"
print
print "Enter a file name for the data. The default file"
print "my_ineptplus can be used by pressing <Enter>. Any file"
print "with the same name will be overwritten without warning."
print
input "Enter output file name (data\my_ineptplus): ",f$
if f$="" then f$="data\my_ineptplus"
100 cls
print "Running INEPT+..."
REM write 2D file header if running more than 1 block...
if b>1 then WH2D f$ b 0 0
REM Phase cycle
a$ = "0000000022222222"
b$ = "0000111122223333"
c$ = "0202131302021313"
d$ = "0022113300221133"
n$ = "0000000022222222"
o$ = "0202020202020202"
p$ = "1133113311331133"
PROGRAM "clear"
PROGRAM 0 d0 S 
PROGRAM + 2.0 uS FX PX 
PROGRAM + p5 uS DEC HP FX PX n$
PROGRAM + d2 uS FX PX 
PROGRAM + p6 uS DEC HP FX PX o$
PROGRAM + p1 uS TX FX PX a$
PROGRAM + d2 uS FX PX
PROGRAM + p5 uS DEC HP FX PX p$
PROGRAM + p0 uS TX FX PX b$
PROGRAM + d3 uS FX PX
PROGRAM + p6 uS DEC HP FX PX o$
PROGRAM + p1 uS TX FX PX c$ 
PROGRAM + d3 uS FX PX
PROGRAM + p5 uS DEC HP FX PX n$
PROGRAM + 1.0 uS ADC RX FX PX
PROGRAM + a S RX FX PX
PROGRAM + 0.02 S RX FX PX 
PROGRAM "coadd" d$
PROGRAM + 1.0 uS
for i=1 to b
ZERO
START
if i=1 then wr "c:\eft\data\pnmr.fid"
if b=1 then goto 200
w=d0*i
WF f$ i w
cls
print "Running INEPT+..."
print
print "Block",i,"of",b,"completed."
NEXT
200 cls
print "INEPT+ Experiment completed."
if b=1 then goto 300
print
print "Block averaging experiment completed. Total scans",n*(i-1),"."
input "<Enter> to continue...",g$
cls
print "Use <Alt+Tab> to transfer to NUTS for data processing."
print "First import and process the first block <a1>, select an"
print "isolated peak for registration, create zoom region 0 about it."
print "Then run aii_Cbapr.mac, which will align and add all blocks."
input "<Enter> to continue...",g$
cls
print "The raw data is saved as file",f$,"which will be"
print "overwritten without warning if the same name is used"
print "again. To save the data move it to another directory."
300 input "<Enter> to exit the pulse program...",g$
END