REM ***********************************************************************
REM *                                                                     *
REM *             1D INADEQUATE pulse program - 000205, GMB               *
REM *                                                                     *
REM * Incredible Natural Abundance Double QUAntum Transfer Experiment.    *  
REM * For the detection of 13C-13C directly coupled systems through the   *
REM * generation of double quantum coherence. The pulse sequnce is:       *
REM *                                                                     *
REM * 13C: 90(x) - d1 - 180(y) - d1 - 90(x) - d2 - 90(phi) - Acqu(psi)    *
REM *                                                                     *
REM * 1H:  BBDEC BBDEC BBDEC BBDEC BBDEC BBDEC BBDEC BBDEC BBDEC BBDEC    *
REM *                                                                     *
REM * d1 is set to 1/4JCC, and d2 is set to 2 uS. The phase cylce for the *
REM * read pulse and the receiver are designed to select double quantum   *
REM * and filter single quantum (isolated 13C nuclei) coherence.          *
REM *                                                                     *
REM ***********************************************************************
showwin
cls
REM Do not read 1C conditions, as we may want to be able to
REM change the number of scans interactively...
print "INADEQUATE Pulse Program for 13C-13C Connectivity."
print 
print "The relaxation delay needs to be set in the range 1 to 5"
print "times the expected T1 for the sample. 2.0 sec is a good"
print "general purpose value."
print
input "Enter a relaxation delay: ",d0
if d0=0 then d0=2
cls
print "INADEQUATE Pulse Program for 13C-13C Connectivity."
print 
print "Setup the 13C pulsewidths."
print
define p0 x90 pulses.txt
if p0=0 then input "Enter the Observe 90 degree pulsewidth: ",p0
if p0>0 then print "The Observe 90 deggree pulsewidth is ",p0,"us"
p1=2*p0
SLEEP 1
cls
print "INADEQUATE Pulse Program for 13C-13C Connectivity."
print 
print "By selecting the proper delays, DQC from different"
print "13C-13C spin systems can be detected. The value of"
print "the JCC will depend on the type of molecule and"
print "bond. Enter a JCC value for detection of DQC in Hz."
input "JCC coupling constant (Hz): ",j
REM In function of j calculate d1...
d1=1e6/(4*j)
d2=2
cls
print "INADEQUATE Pulse Program for 13C-13C Connectivity."
print
print "Enter the number of blocks of data to acquire (default 1)."
print "Entering more than 1 block will automatically set the"
print "spectrometer to run in block averaging mode."
input "Number of blocks of data to acquire: ",b
if b<1 then b=1
if b=1 then goto 100
cls
print "INADEQUATE Pulse Program for 13C-13C Connectivity."
print 
print "Enter a file name for the data. The default file"
print "my_indq can be used by pressing <Enter>. Any file"
print "with the same name will be overwritten without warning."
print
input "Enter output file name (data\my_indq): ",f$
if f$="" then f$="data\my_indq"
100 cls
print "INADEQUATE Pulse Program for 13C-13C Connectivity."
print
if b>1 then print "The spectrometer is set to do",b,"blocks of",n,"scans each."
if b>1 then print
print "Running INADEQUATE. Hope you have a thick sample..."
REM write 2D file header if running more than 1 block...
if b>1 then WH2D f$ b 0 0
REM Minimal phase cycle for experimentation. Just DQF selection...
a$ = "0000"
b$ = "0000"
c$ = "0321"
d$ = "0123"
PROGRAM "clear"
PROGRAM 0 d0 S DEC BB FX PX
PROGRAM + 2.0 uS DEC BB FX PX
PROGRAM + p0 uS TX DEC BB FX PX a$
PROGRAM + d1 uS DEC BB FX PX
PROGRAM + p1 uS TX DEC BB FX PX b$
PROGRAM + d1 uS DEC BB FX PX
PROGRAM + p0 uS TX DEC BB FX PX a$
PROGRAM + d2 uS DEC BB FX PX
PROGRAM + p0 uS TX DEC BB FX PX c$
PROGRAM + 1.0 uS ADC RX DEC BB FX PX
PROGRAM + a S RX DEC BB FX PX
PROGRAM + 0.02 S RX DEC BB FX PX 
PROGRAM "coadd" d$
PROGRAM + 1.0 uS DEC BB FX PX
FOR i=1 to b
print
ZERO
START
w=d0*i
if i=1 then wr "c:\eft\data\pnmr.fid"
if b=1 then goto 200
WF f$ i w
cls
print "Running INADEQUATE..."
print
print "Block",i,"of",b,"completed."
NEXT
200 cls
print "INADEQUATE Experiment completed."
if b=1 then goto 300
print
print "Block averaging experiment completed. Total scans",n*(i-1),"."
input "<Enter> to continue...",g$
cls
print "Use <Alt+Tab> to transfer to NUTS for data processing."
print "First import and process the first block <a1>, select an"
print "isolated peak for registration, create zoom region 0 about it."
print "Then run aii_Cbapr.mac, which will align and add all blocks."
input "<Enter> to continue...",g$
cls
print "The raw data is saved as file",f$,"which will be"
print "overwritten without warning if the same name is used"
print "again. To save the data move it to another directory."
300 input "<Enter> to exit the pulse program...",g$
END