REM ***********************************************************************
REM *                                                                     *
REM *                        HETERO2DJ - GMB 2000                         *
REM *                                                                     *
REM * Heteronuclear J-spectrosopy with magnitude mode collection. 1H-13C  *
REM * couplings in F1, 13C chemical shifts in F2. Uses pulse  sequence:   *
REM *                                                                     *
REM *           13C: 90(x) - t1/2 - 180(y) - t1/2 - Acq(x)                *
REM *                                                                     *
REM *            1H:  -------------- 180(y) -------- BBDEC                *
REM *                                                                     *
REM * d1 is incremented so that the f1 size ends up as the value entered  *
REM * by the user. The increment should therefore be 1/f1, where f1 is    *
REM * the maximum frequency (coupling) in the f1 dimenssion. The phasing  *
REM * follows the EXORCYLCE scheme.                                       *
REM *                                                                     *
REM ***********************************************************************
REM read in het2dj conditions
re "c:\eft\c13\hetero2dj.ini"
showwin
cls
print "HETERO2DJ Acquisition Program for 13C J-Spectroscopy."
print 
print "The relaxation delay needs to be set in the range 1 to 5"
print "times the expected T1 for the sample. 2.0 sec is a good"
print "general purpose value."
print
input "Enter a relaxation delay.",d0
cls
print "HETERO2DJ Acquisition Program for 13C J-Spectroscopy."
print 
print "Setup the 13C and 1H pulsewidths."
define p5 h90 pulses.txt
if p5=0 then input "Enter the Decoupler 90 degree pulsewidth ",p5,"us"
if p5>0 then print "The Decoupler 90 degree pulsewidth is ",p5,"us"
p6=2*p5
define p0 x90 pulses.txt
if p0=0 then input "Enter the Observe 90 degree pulsewidth ",p0,"us"
if p0>0 then print "The Observe 90 deggree pulsewidth is ",p0,"us"
p1=2*p0
SLEEP 1
cls
print "HETERO2DJ Acquisition Program for 13C J-Spectroscopy."
print 
print "Enter the size (in Hz) of the F1 dimension. The default"
print "size is 500 Hz, which covers most of the 13C-1H coupling"
print "constants in organic molecules."
input "Enter the size (Hz) of the F1 dimension: ",v
if v=0 then v=500
REM We need to sample twice as much in F1 (good'ol Nyquist...)
d2=1e6/(2*v)
cls
print "HETERO2DJ Acquisition Program for 13C J-Spectroscopy."
print 
print "Enter the number of experiment in the F1 dimenssion."
print "Usually, 64 are enough, and more will not be beneficial"
print "due to relaxation."
input "Number of experiments in F1: ",x
REM if the user selects more than 128, force it to 128...
if x=0 then x=64
if x>128 then x=128
print
print "Resolution in F1 dimenssion (Hz): ",v/x
REM This can be improved by zero-filling...
SLEEP 1
cls
print "HETERO2DJ Acquisition Program for 13C J-Spectroscopy."
print 
print "Enter a file name for the data. The default file"
print "my_het2dj can be used by pressing with an <Enter>. Any file"
print "with the same name will be overwritten without warning."
input "Enter output file name, e.g. data\my_het2dj<Enter>: ",f$
if f$="" then f$="data\my_het2dj"
REM calculate the run time with the revised RD.
w=n*x*(a+d0+x*d2/2e6)/60
REM print decent significant figures.
w=(10*w - (10*w)%1)/10
REM initial t1 delay
d1=1.0 'microseconds
REM Write the 2D file header
WH2D f$ x v 90.02
REM will use 3*dw/16 delay before turning receiver on
e=3*d/16
REM will use dw/16 delay before turning digitizer on
f=d/16
REM now run the HETERO2DJ experiment
cls
print "Running HETERO2DJ..."
print
print "Time, in minutes, to complete the experiment: ",w
REM 90 13C pulse phase
a$ = "0000"
REM 180 13C pulse phase
b$ = "0123"
REM receiver phase
c$ = "0202"
REM DEC 180 pulse phase
o$ = "0000"
PROGRAM "clear"
PROGRAM 0 d0 S
PROGRAM + 2.0 uS 
PROGRAM + p0 uS TX FX PX a$
PROGRAM + d1 uS 
PROGRAM + p1 uS TX FX PX b$
PROGRAM + p6 uS DEC HP FX PX o$
PROGRAM + d1 uS 
PROGRAM + e uS DEC BB FX PX 
PROGRAM + f uS RX DEC BB FX PX
PROGRAM + 1.0 uS ADC RX DEC BB FX PX
PROGRAM + a S RX DEC BB FX PX
PROGRAM "coadd" c$
PROGRAM + 1.0 uS
FOR i=1 to x
ZERO
START
REM Write the data to the 2D file
WF f$ i 0
REM Increment the t1 delay by d2 and update pulse programer...
d1=d1+d2
PROGRAM 3 d1 uS
PROGRAM 6 d1 uS
cls
print "Running HETERO2DJ..."
print
REM calculate the remaining time.
w=n*(x-i)*(a+d0+x*d2/2e6)/60
REM print decent significant figures.
w=(10*w - (10*w)%1)/10
print "Slice",i,"of",x,"completed - Time remaining",w,"minutes."
NEXT
cls
print "HETRO2DJ Experiment Completed."
print
print "Data written to file ",f$
print
print "Use NutsMacro usp_hetero2dj.mac for processing."
input "<Enter> to exit the pulse program.",g$
END