REM ***********************************************************************
REM *                                                                     *
REM *                          DQFCOSY - GMB 2000                         *
REM *                                                                     *
REM * Double quantum filtered COSY experiment, for filtering zero-quantum *
REM * transitions. Eliminates 'singlets' from the diagonal and thus gives *
REM * a much cleaner spectrum. The pulse sequence is:                     *
REM *                                                                     *
REM *                   rd - p0 - d0 - p1 - p2 - acquire                  *
REM *                                                                     *
REM * TD=SI, number of t1 experiments, x=TD/4, and zero fill in the       *
REM * second dimension. p0, p1, and p2 are 90 degree pulses, d is the     *
REM * dwell time and, the time increment in the t1 dimension. The eight-  *
REM * step phase cycle is required for the filter, and it is adecuate to  *
REM * give phase-sensitive data instead of magnitude mode.                *
REM *                                                                     *
REM ***********************************************************************
REM read in cosyph conditions (8 scans...)
re "c:\eft\h1\cosyph.ini"
showwin
cls
print "DQF-COSY acquisition program"
print 
print "The relaxation delay needs to be set in the range 1 to 5"
print "times the expected T1 for the sample. 2.0 sec is a good"
print "general purpose value."
print
input "Enter a relaxation delay: ",d0
cls
print "DQF-COSY acquisition program"
print 
define p0 h90 pulses.txt
if p0=0 then input "Enter 90 degree pulsewidth: ",p0
if p0>0 then print "The 90 degree pulsewidth chosen is ",p0
SLEEP 1
cls
print "DQF-COSY acquisition program"
print 
print "Enter a file name for the data. The default file"
print "my_dqfcosy can be used by responding with an <Enter>."
print "Any file with the same name will be overwritten"
print "without warning."
input "Enter output file name, e.g. data\my_dqfcosy<Enter>. ",f$
if f$="" then f$="data\my_dqfcosy"
REM first pulse phase...
a$="01232301"
REM second pulse phase...
b$="01230123"
REM third pulse phase...
c$="00000000"
REM receiver phase...
d$="02022020"
REM will use 3*dw/16 delay before turning receiver on
e=3*d/16
REM will use dw/16 delay before turning digitizer on
f=d/16
REM set up the program for GS
PROGRAM "clear"
PROGRAM 0 d0 S
PROGRAM + 2.0 uS    
PROGRAM + p0 uS TX a$
PROGRAM + e uS
PROGRAM + f uS RX
PROGRAM + 1.0 uS ADC RX
PROGRAM + a S RX
PROGRAM "coadd" c$
PROGRAM + 2.0 uS
ZERO
cls
print "Running GS..."
print
print "If the FID is RED, reduce the gain. <Ctrl+G>"
print
print "<Ctrl+Q> to exit GS and continue with DQF-COSY."
STARTGS
REM now run the DQF-COSY experiment
REM initial t1 delay
d1=1.0 'microseconds
REM Number of t1 slices SI/4=TD/4, TD=t
x=t/4
REM calculate the run time with the revised RD and all the other junk...
w=n*x*(a+d0+x*d/2e6)/60
REM print decent significant figures.
w=(10*w - (10*w)%1)/10
REM define nucleus for 2nd dimension
h$="H1"
REM Write the 2D file header
WH2D f$ x s h$
cls
print "Running DQF-COSY..."
print
print "Time, in minutes, to complete the experiment. ",w
print
PROGRAM "clear"
PROGRAM 0 d0 S
PROGRAM + 2.0 uS    
PROGRAM + p0  uS TX a$
PROGRAM + d1  uS    
PROGRAM + p0  uS TX b$
PROGRAM + 2.0 uS
PROGRAM + p0  uS TX c$
PROGRAM + e uS
PROGRAM + f uS RX
PROGRAM + 1.0 uS ADC RX
PROGRAM + a S RX
PROGRAM "coadd" d$
PROGRAM + 2.0 uS
FOR i=1 to x
ZERO
START
REM Write the data to the 2D file
WF f$ i 0
REM Increment the t1 delay by d and update pulse programer...
d1=d1+d
PROGRAM 3 d1 uS
cls
print "Running DQF-COSY..."
print
REM calculate the remaining time.
w=n*(x-i)*(a+d0+x*d/2e6)/60
REM print decent significant figures.
w=(10*w - (10*w)%1)/10
print "Slice",i,"of",x,"completed - Time remaining",w,"minutes."
NEXT
cls
print "DQF-COSY Experiment Completed."
print
print "Data written to file ",f$
print
print "Use NutsMacro aii_cosy.mac, <Ctrl+F5>, for processing."
input "<Enter> to exit the pulse program.",g$
END