REM ***********************************************************************
REM *                                                                     *
REM *                          CALIB90 - GMB 2000                         *
REM *                                                                     *
REM * This pulse sequence is very simple. It will just do a series of 1D  *
REM * experiments using varying pulse widths, and will store the results  *
REM * as a file that can be analyzed with NUTS. The sequence is:          *
REM *                                                                     *
REM *                          rd - p1 - acquire                          *
REM *                                                                     *
REM * The user needs to enter the pulse widths of the first and last      *
REM * pulses, the number of experiments, and the program will calculate   *
REM * the increment per experiment accordingly. You can calibrate either  *
REM * the transmiter or the decoupler 90 degree pulses.                   *
REM *                                                                     *
REM ***********************************************************************
rem save original conditions..
wr "c:\eft\temp.ini"
showwin
cls
print "CALIB90 - Calibration of 1H 90 degree pulses"
print
print "This program is intended for calibrating the 1H"
print "90 degree pulse for the transmiter, as well as"
print "the low power decoupler 1H 90 degree pulse for use"
print "with some homonuclear decoupling schemes (MLEV-17)
print "and selective excitation (DANTE trains)."
print
print "Enter (0) to calibrate the transmiter, or (1) to"
print "calibrate the decoupler low power 90 degree pulse"
input "Calibrate transmiter (0) or decoupler (1): ",w
cls
print "CALIB90 - Calibration o 1H 90 degree pulses"
print
print "The program will loop over a range of pulse widhts."
print "You need to specify the first and last pulse widths"
print "and the number of experiments, and the program will"
print "calculate the increments in pulse width per experiment."
input "First pulse width: ", p0
input "Last pulse width: ", p1
input "Number of experiments: ",l
rem Calculate the increment for p0...
p1=(p1-p0)/l
cls
print "CALIB90 - Calibration of 1H 90 degree pulses"
print
print "Since the pulse sequence will be repeated, a reasonable"
print "repetition delay is needed between pulses. If the delay"
print "is too short, you will get erroneous results. A value of"
print "5 to 10 seconds is appropriate form most samples."
input "Repetition delay (s): ", d0
cls
print "CALIB90 - Calibration of 1H 90 degree pulses"
print
print "Enter a file name for the data. The default file"
print "my_calib90 can be used by responding with an <Enter>."
print "Any file with the same name will be overwritten"
print "without warning."
input "Enter output file name (data\my_calib90): ",f$
if f$="" then f$="data\my_calib90"
REM Write the 2D file header
WH2D f$ l 0 0
cls
print "CALIB90 - Calibration of 1H 90 degree pulses"
print
print "The spectrometer is set to do",l,"experiments,"
print "starting with a pulse width of",p0,"us, and will"
print "use and increment of",p1,"us per experiment."
SLEEP 1
REM will use 3*dw/16 delay before turning receiver on
e=3*d/16
REM will use dw/16 delay before turning digitizer on
f=d/16
rem a$ is the transmiter/receiver phase cycle
a$ = "0"
PROGRAM "clear"
PROGRAM 0 d0 S
PROGRAM + 2 uS
if w=1 then PROGRAM + p0 uS DEC FX PX a$
if w=0 then PROGRAM + p0 us TX a$
PROGRAM + e uS
PROGRAM + f uS RX
PROGRAM + 1.0 uS ADC RX
PROGRAM + a S RX
PROGRAM "coadd" a$
PROGRAM + 1 uS
for i=1 to l
ZERO
START
d1=d0*i
WF f$ i d1
if i=1 then wr "c:\eft\data\pnmr.fid"
rem Modify the pulse width and update the pulse programmer...
p0=p0+p1
if w=1 then PROGRAM 2 p0 uS DEC FX PX a$
if w=0 then PROGRAM 2 p0 us TX a$
cls
print "Running CALIB90..."
print
print "Experiment",i,"of",l,"completed."
NEXT
SLEEP 1
cls
print "CALIB90 Experiment Completed."
print
print "Data written to file ",f$
print
print "Use <Alt+Tab> to transfer to Nuts in order to process the data"
print "First import and process the first experiment <a1>, and phase"
print "the spectrum for pure absorptive signals. Then run the macro"
print "usp_calib90.mac, which will perform all the calculations and"
print "report the value of the 90 degree pulse."
input "<Enter> to exit the pulse program.",g$
re "c:\eft\temp.ini"
END